{tango-idl, tango-cpp, tango-database, jive}: init

pkgs/by-name/ji/jive/package.nix

@@ -0,0 +1,40 @@
+{
+  stdenv,
+  lib,
+  fetchurl,
+  makeWrapper,
+  jre,
+}:
+stdenv.mkDerivation rec {
+  pname = "jive";
+  version = "7.45";
+
+  src = fetchurl {
+    url = "https://repo.maven.apache.org/maven2/org/tango-controls/Jive/${version}/Jive-${version}-jar-with-dependencies.jar";
+    hash = "sha256-a/I4jMlTVYWN9zNBQnWbvT2MBHItexnwPly1XyOeR8U=";
+  };
+
+  dontUnpack = true;
+
+  nativeBuildInputs = [ makeWrapper ];
+
+  installPhase = ''
+    runHook preInstall
+
+    mkdir -p $out/bin $out/share/java
+    cp $src $out/share/java/jive.jar
+    makeWrapper ${jre}/bin/java $out/bin/jive \
+      --add-flags "-classpath $out/share/java/jive.jar jive3.MainPanel"
+
+    runHook postInstall
+  '';
+
+  meta = {
+    description = "Standalone JAVA application designed to browse and edit the static TANGO database";
+    homepage = "https://gitlab.com/tango-controls/jive";
+    license = lib.licenses.gpl3;
+    platforms = lib.platforms.unix;
+    maintainers = [ lib.maintainers.gilice ];
+    sourceProvenance = [ lib.sourceTypes.binaryBytecode ];
+  };
+}

pkgs/by-name/ta/tango-cpp/package.nix

@@ -0,0 +1,63 @@
+{
+  stdenv,
+  lib,
+  cmake,
+  cppzmq,
+  curl,
+  fetchFromGitLab,
+  fetchpatch,
+  libjpeg,
+  omniorb,
+  openssl,
+  opentelemetry-cpp,
+  protobuf,
+  tango-idl,
+  zeromq,
+}:
+stdenv.mkDerivation rec {
+  pname = "tango-cpp";
+  version = "10.1.1";
+
+  src = fetchFromGitLab {
+    owner = "tango-controls";
+    repo = "cppTango";
+    tag = version;
+    fetchSubmodules = true;
+    hash = "sha256-Edv7ZGnESjpuwt0Hentl0qgV2PfBgXWED7v9pUvTW0o=";
+  };
+
+  patches = [
+    # corresponds to PR https://gitlab.com/tango-controls/cppTango/-/merge_requests/1525
+    (fetchpatch {
+      url = "https://gitlab.com/tango-controls/cppTango/-/commit/66bd2d9deb79fb557eb2314376f9559e7476d3a1.patch";
+      hash = "sha256-ZUcBS4apVfXmXKnpGOQJ9DF8t79qJ2yqKXwaseiOC6U=";
+    })
+  ];
+
+  nativeBuildInputs = [
+    cmake
+    cppzmq
+    tango-idl
+  ];
+
+  buildInputs = [
+    curl
+    libjpeg
+    omniorb
+    openssl
+    (opentelemetry-cpp.override {
+      enableGrpc = true;
+      enableHttp = true;
+    })
+    protobuf
+    zeromq
+  ];
+
+  meta = {
+    description = "Tango Distributed Control System - C++ library";
+    homepage = "https://gitlab.com/tango-controls/cppTango";
+    license = lib.licenses.lgpl3;
+    platforms = lib.platforms.linux;
+    maintainers = [ lib.maintainers.gilice ];
+  };
+}

pkgs/by-name/ta/tango-database/package.nix

@@ -0,0 +1,67 @@
+{
+  stdenv,
+  lib,
+  cmake,
+  cppzmq,
+  fetchFromGitLab,
+  libjpeg,
+  mariadb,
+  mariadb-connector-c,
+  omniorb,
+  opentelemetry-cpp,
+  protobuf,
+  tango-cpp,
+}:
+
+# NOTE: You need to manually set up the database structure to run Tango successfully.
+# See $out/share/tango/db/create_db.sh
+stdenv.mkDerivation rec {
+  pname = "tango-database";
+  version = "5.25";
+
+  src = fetchFromGitLab {
+    owner = "tango-controls";
+    repo = "TangoDatabase";
+    tag = "Database-Release-${version}";
+    fetchSubmodules = true;
+    hash = "sha256-hu2TIPxXyUtLK3bHFHuBYho23TGLkmsHfxEabsjsvmE=";
+  };
+
+  nativeBuildInputs = [
+    cmake
+  ];
+
+  buildInputs = [
+    cppzmq
+    libjpeg
+    mariadb.client
+    mariadb-connector-c.dev
+    omniorb
+    (opentelemetry-cpp.override {
+      enableGrpc = true;
+      enableHttp = true;
+    })
+    protobuf
+    tango-cpp
+  ];
+
+  # their FindMySQL.cmake fails to find these libraries,
+  # maybe because mariadb-connector-c puts its libraries into $out/lib/mariadb, not $out/lib?
+  cmakeFlags = [
+    "-DMySQL_INCLUDE_DIR=${mariadb-connector-c.dev}/include/mysql"
+    "-DMySQL_LIBRARY_DEBUG=${mariadb-connector-c}/lib/mariadb/libmariadb.so"
+    "-DMySQL_LIBRARY_RELEASE=${mariadb-connector-c}/lib/mariadb/libmariadb.so"
+  ];
+
+  postFixup = ''
+    patchelf --add-rpath ${mariadb-connector-c}/lib/mariadb $out/bin/Databaseds
+  '';
+
+  meta = {
+    description = "Tango distributed control system - database server";
+    homepage = "https://gitlab.com/tango-controls/TangoDatabase";
+    license = lib.licenses.gpl3Plus;
+    platforms = lib.platforms.linux;
+    maintainers = [ lib.maintainers.gilice ];
+  };
+}

pkgs/by-name/ta/tango-idl/package.nix

@@ -0,0 +1,36 @@
+{
+  stdenv,
+  lib,
+  fetchFromGitLab,
+  fetchpatch,
+  cmake,
+}:
+stdenv.mkDerivation rec {
+  pname = "tango-idl";
+  version = "6.0.4";
+
+  src = fetchFromGitLab {
+    owner = "tango-controls";
+    repo = "tango-idl";
+    tag = version;
+    hash = "sha256-etXjey4X5mNCHLtu3TyQv0S9uP4BSfZVNN8YDc/fp68=";
+  };
+
+  patches = [
+    # corresponds to PR https://gitlab.com/tango-controls/tango-idl/-/merge_requests/31/
+    (fetchpatch {
+      url = "https://gitlab.com/tango-controls/tango-idl/-/commit/8fd75a4079bf96544697f7783c2de0027d030b8e.patch";
+      hash = "sha256-2NMfHakoHzxnYqxVDvH2LnEtLe8S8K88prT9AAs95MA=";
+    })
+  ];
+
+  nativeBuildInputs = [ cmake ];
+
+  meta = {
+    description = "Tango CORBA IDL file";
+    homepage = "https://gitlab.com/tango-controls/tango-idl";
+    license = lib.licenses.lgpl3;
+    platforms = lib.platforms.unix;
+    maintainers = [ lib.maintainers.gilice ];
+  };
+}