android_module_common.gradle

/*
 * File: 'android_module_common.gradle'
 * Location: https://raw.githubusercontent.com/yongce/AndroidLib/master/android_module_common.gradle
 * Version: 2021.10.1
 * All android projects can copy and include this file.
 */

import org.gradle.api.DefaultTask
import org.gradle.api.GradleException
import org.gradle.api.file.DirectoryProperty
import org.gradle.api.tasks.InputDirectory
import org.gradle.api.tasks.OutputDirectory
import org.gradle.api.tasks.TaskAction

import java.nio.file.Files
import java.nio.file.StandardCopyOption

abstract class CopyApksToAppsOutTask extends DefaultTask {
    @InputDirectory
    abstract DirectoryProperty getApkFolder()

    @OutputDirectory
    abstract DirectoryProperty getOutputDirectory()

    @TaskAction
    void copyApks() {
        def sourceDir = apkFolder.get().asFile
        if (!sourceDir.exists()) {
            throw new GradleException("Cannot load APKs from ${sourceDir}")
        }

        def targetDir = outputDirectory.get().asFile
        if (!targetDir.exists()) {
            targetDir.mkdirs()
        }
        sourceDir.eachFileRecurse { file ->
            if (file.isFile() && file.name.endsWith(".apk")) {
                Files.copy(
                        file.toPath(),
                        new File(targetDir, file.name).toPath(),
                        StandardCopyOption.REPLACE_EXISTING
                )
            }
        }
    }
}

// Define some common closures (methods) for code share
ext.getModuleProjectCommitCount = {
    String gitCommitCountCmd = "git rev-list HEAD --count"
    Process process = gitCommitCountCmd.execute((String[])null, project.projectDir)
    String errText = process.err.text
    try {
        return process.text.trim().toInteger()
    } catch (Exception e) {
        println String.format("Failed to execute #getModuleProjectCommitCount() with error [%s], " +
                "which is caused by [%s].", e.toString(), errText)
    }
}

ext.getModuleProjectLastCommitSha1 = {
    String gitCommitCountCmd = "git log --format=\"%H\" -1"
    String cmdResult = gitCommitCountCmd.execute((String[])null, project.projectDir).text
    return cmdResult.trim().replace('\"', '')
}

ext.getRootProjectLastCommitSha1 = {
    String gitCommitCountCmd = "git log --format=\"%H\" -1"
    String cmdResult = gitCommitCountCmd.execute((String[])null, rootProject.projectDir).text
    return cmdResult.trim().replace('\"', '')
}

ext.getBuildIdSuffix = {
    if (project.hasProperty('build_id')) {
        return "." + project.property('build_id')
    }
    return ""
}

ext.isIgnoreLintWarnings = {
    if (project.hasProperty('lint_ignore_warnings')) {
        return true
    }
    return false
}

ext.isApkSplitsEnabled = {
    return project.hasProperty('enable_apk_splits')
}

ext {
    calculatedVersionCode = getModuleProjectCommitCount()
    buildIdSuffix = getBuildIdSuffix()
}

android {
    compileSdk = versions.compileSdk

    defaultConfig {
        manifestPlaceholders = [
                MODULE_GIT_COMMIT_SHA1: getModuleProjectLastCommitSha1(),
                ROOT_GIT_COMMIT_SHA1: getRootProjectLastCommitSha1()
        ]

        testInstrumentationRunner "androidx.test.runner.AndroidJUnitRunner"
    }

    if (project.plugins.hasPlugin("com.android.application")) {
        signingConfigs {
            androidTestKey {
                storeFile file("${rootDir}/aosp.keystore")
                storePassword "android"
                keyAlias "android.testkey"
                keyPassword "android"
            }

            androidPlatformKey {
                storeFile file("${rootDir}/aosp.keystore")
                storePassword "android"
                keyAlias "android.platformkey"
                keyPassword "android"
            }
        }

        buildTypes {
            debug {
                signingConfig = signingConfigs.androidTestKey
            }

            release {
                signingConfig = signingConfigs.androidTestKey

                minifyEnabled = true
                proguardFiles getDefaultProguardFile('proguard-android-optimize.txt'), 'proguard-rules.pro'
            }
        }

    }

    if (project.plugins.hasPlugin("com.android.application")) {
        androidComponents {
            onVariants(selector().withBuildType("release")) { variant ->
                variant.outputs.each { output ->
                    String fileName = "${project.name}"
                    if (variant.flavorName != null && !variant.flavorName.isEmpty()) {
                        fileName += "-${variant.flavorName}"
                    }

                    String abi = output.filters.find {
                        it.filterType.name() == "ABI"
                    }?.identifier
                    if (abi != null && !abi.isEmpty()) {
                        fileName += "-${abi}"
                    }

                    fileName += "-${output.versionName.get()}-${output.versionCode.get()}"
                    output.outputFileName.set("${fileName}.apk")
                }

                File appsOutDir = rootProject.file(rootProject.ext.appsOutDir)
                def copyApksTask = tasks.register("copy${variant.name.capitalize()}ApksToAppsOut", CopyApksToAppsOutTask) {
                    def apkArtifact = variant.artifacts.class.classLoader
                            .loadClass("com.android.build.api.artifact.SingleArtifact\$APK")
                            .INSTANCE
                    apkFolder.set(variant.artifacts.get(apkArtifact))
                    outputDirectory.set(appsOutDir)
                }

                String assembleTaskName = "assemble${variant.name.capitalize()}"
                tasks.configureEach {
                    if (name == assembleTaskName) {
                        finalizedBy(copyApksTask)
                    }
                }
            }
        }
    }

    lint {
        textReport = true

        abortOnError = true
        ignoreWarnings = isIgnoreLintWarnings()
    }

    compileOptions {
        sourceCompatibility JavaVersion.VERSION_11
        targetCompatibility JavaVersion.VERSION_11
    }

    testOptions {
        unitTests.all {
            systemProperty "robolectric.enabledSdks", "34"

            // All the usual Gradle options.
            testLogging {
                events "passed", "skipped", "failed", "standardOut", "standardError"
                outputs.upToDateWhen {false}
                showStandardStreams = true
            }
        }

        unitTests {
            includeAndroidResources = true
        }
    }
}