c-vector/flake.nix at master · sockcrates/c-vector · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
{
  description = "c-vector development environment";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
  };

  outputs = { self, nixpkgs }:
    let
      systems = [
        "x86_64-linux"
        "aarch64-linux"
        "x86_64-darwin"
        "aarch64-darwin"
      ];
      forAllSystems = f: nixpkgs.lib.genAttrs systems (system: f system);
    in
    {
      packages = forAllSystems (system:
        let
          pkgs = import nixpkgs { inherit system; };
        in
        {
          default = pkgs.stdenv.mkDerivation {
            pname = "c-vector";
            version = "0.1.0";
            src = ./.;

            nativeBuildInputs = with pkgs; [
              llvmPackages_18.clang
              gnumake
            ];

            buildPhase = ''
              export CC=clang
              make build_lib
            '';

            installPhase = ''
              mkdir -p $out/lib $out/include
              cp build/libvector.a $out/lib/
              cp -r include/. $out/include/
            '';
          };
        });

      devShells = forAllSystems (system:
        let
          pkgs = import nixpkgs { inherit system; };
          clang = pkgs.llvmPackages_18.clang;
          clangTools = pkgs.llvmPackages_18.clang-tools;
          clangdWrapped = pkgs.writeShellScriptBin "clangd" ''
            exec ${clangTools}/bin/clangd --query-driver=${clang}/bin/clang "$@"
          '';
        in
        {
          default = pkgs.mkShell {
            packages = with pkgs; [
              clangdWrapped
              clang
              clangTools
              gnumake
            ];

            shellHook = ''
              export CC=${clang}/bin/clang
            '';
          };
        });
    };
}