Add configuration options for disabling Prometheus endpoints and metrics

Author: kenliao94

deps/rabbitmq_prometheus/priv/schema/rabbitmq_prometheus.schema

@@ -148,3 +148,23 @@ end}.
 %% Authentication options ========================================================
 {mapping, "prometheus.authentication.enabled", "rabbitmq_prometheus.authentication.enabled",
     [{datatype, {enum, [true, false]}}]}.
+
+%% Endpoint disable options ========================================================
+{mapping, "prometheus.disable_memory_breakdown_endpoint", "rabbitmq_prometheus.disable_memory_breakdown_endpoint",
+    [{datatype, {enum, [true, false]}}, {default, false}]}.
+
+{mapping, "prometheus.disable_per_object_endpoint", "rabbitmq_prometheus.disable_per_object_endpoint",
+    [{datatype, {enum, [true, false]}}, {default, true}]}.
+
+{mapping, "prometheus.disable_detailed_endpoint", "rabbitmq_prometheus.disable_detailed_endpoint",
+    [{datatype, {enum, [true, false]}}, {default, false}]}.
+
+%% Metric blocklist options ========================================================
+{mapping, "prometheus.disabled_metrics.$metric", "rabbitmq_prometheus.disabled_metrics",
+    [{datatype, atom}]}.
+
+{translation, "rabbitmq_prometheus.disabled_metrics",
+fun(Conf) ->
+    Settings = cuttlefish_variable:filter_by_prefix("prometheus.disabled_metrics", Conf),
+    [V || {_, V} <- Settings]
+end}.

deps/rabbitmq_prometheus/src/collectors/prometheus_rabbitmq_core_metrics_collector.erl

@@ -472,6 +472,7 @@ add_metric_family({Name, Type, Help, Metrics}, Callback) ->
     Callback(create_mf(MN, Help, Type, Metrics)).
 
 mf(Callback, Prefix, Contents, Data) ->
+    DisabledMetrics = normalize_disabled_metrics(application:get_env(rabbitmq_prometheus, disabled_metrics, [])),
     _ = [begin
          Fun = case Conversion of
                    undefined ->
@@ -488,7 +489,7 @@ mf(Callback, Prefix, Contents, Data) ->
                 {Type, Fun, Data}
             )
         )
-    end || {Index, Conversion, Name, Type, Help} <- Contents],
+    end || {Index, Conversion, Name, Type, Help} <- Contents, not lists:member(Name, DisabledMetrics)],
     [begin
         Fun = case Conversion of
                   undefined ->
@@ -505,7 +506,18 @@ mf(Callback, Prefix, Contents, Data) ->
                 {Type, Fun, Data}
             )
         )
-    end || {Index, Conversion, Name, Type, Help, Key} <- Contents].
+    end || {Index, Conversion, Name, Type, Help, Key} <- Contents, not lists:member(Name, DisabledMetrics)].
+
+normalize_disabled_metrics(Metrics) ->
+    [normalize_metric_name(M) || M <- Metrics].
+
+normalize_metric_name(Metric) when is_atom(Metric) ->
+    case atom_to_list(Metric) of
+        "rabbitmq_detailed_" ++ Rest -> list_to_atom(Rest);
+        "rabbitmq_cluster_" ++ Rest -> list_to_atom(Rest);
+        "rabbitmq_" ++ Rest -> list_to_atom(Rest);
+        _ -> Metric
+    end.
 
 mf_totals(Callback, Name, Type, Help, Size) ->
     Callback(

deps/rabbitmq_prometheus/src/rabbit_prometheus_dispatcher.erl

@@ -35,15 +35,27 @@ build_dispatcher() ->
             true  -> PerObjectCollectors
         end
     ),
-    prometheus_registry:register_collectors('per-object',
-        CoreCollectors ++ PerObjectCollectors),
-    prometheus_registry:register_collectors('detailed', [
-        prometheus_rabbitmq_core_metrics_collector,
-        prometheus_rabbitmq_raft_metrics_collector
-        ]),
-    prometheus_registry:register_collectors('memory-breakdown', [
-        prometheus_rabbitmq_core_metrics_collector
-        ]),
+    case application:get_env(rabbitmq_prometheus, disable_per_object_endpoint, false) of
+        true -> ok;
+        false ->
+            prometheus_registry:register_collectors('per-object',
+                CoreCollectors ++ PerObjectCollectors)
+    end,
+    case application:get_env(rabbitmq_prometheus, disable_detailed_endpoint, false) of
+        true -> ok;
+        false ->
+            prometheus_registry:register_collectors('detailed', [
+                prometheus_rabbitmq_core_metrics_collector,
+                prometheus_rabbitmq_raft_metrics_collector
+            ])
+    end,
+    case application:get_env(rabbitmq_prometheus, disable_memory_breakdown_endpoint, false) of
+        true -> ok;
+        false ->
+            prometheus_registry:register_collectors('memory-breakdown', [
+                prometheus_rabbitmq_core_metrics_collector
+            ])
+    end,
     rabbit_prometheus_handler:setup(),
     cowboy_router:compile([{'_', dispatcher()}]).
 

deps/rabbitmq_prometheus/src/rabbit_prometheus_handler.erl

@@ -44,9 +44,18 @@ is_authorized(ReqData, Context) ->
 
 setup() ->
     setup_metrics(telemetry_registry()),
-    setup_metrics('per-object'),
-    setup_metrics('memory-breakdown'),
-    setup_metrics('detailed').
+    case application:get_env(rabbitmq_prometheus, disable_per_object_endpoint, false) of
+        true -> ok;
+        false -> setup_metrics('per-object')
+    end,
+    case application:get_env(rabbitmq_prometheus, disable_memory_breakdown_endpoint, false) of
+        true -> ok;
+        false -> setup_metrics('memory-breakdown')
+    end,
+    case application:get_env(rabbitmq_prometheus, disable_detailed_endpoint, false) of
+        true -> ok;
+        false -> setup_metrics('detailed')
+    end.
 
 setup_metrics(Registry) ->
     ScrapeDuration = [{name, ?SCRAPE_DURATION},