justfile

set shell := ["bash", "-eu", "-o", "pipefail", "-c"]

app_name := "Weft Status"
bundle := ".build/Weft Status.app"
user_bundle := env_var("HOME") + "/Applications/Weft Status.app"
lsregister := "/System/Library/Frameworks/CoreServices.framework/Frameworks/LaunchServices.framework/Support/lsregister"

default:
    @just --list

build:
    swift build

build-release:
    swift build -c release

run:
    swift run WeftStatus

app: build-release
    mkdir -p "{{bundle}}/Contents/MacOS" "{{bundle}}/Contents/Resources"
    rm -f "{{bundle}}/Contents/MacOS/{{app_name}}" "{{bundle}}/Contents/Info.plist" "{{bundle}}/Contents/PkgInfo" "{{bundle}}/Contents/Resources/AppIcon.svg"
    cp .build/release/WeftStatus "{{bundle}}/Contents/MacOS/{{app_name}}"
    cp App/Info.plist "{{bundle}}/Contents/Info.plist"
    cp App/AppIcon.svg "{{bundle}}/Contents/Resources/AppIcon.svg"
    printf 'APPL????' > "{{bundle}}/Contents/PkgInfo"
    codesign --force --deep --sign - "{{bundle}}"
    @echo "Built {{bundle}}"

install-user: app
    mkdir -p "$HOME/Applications"
    rm -rf "{{user_bundle}}"
    cp -R "{{bundle}}" "{{user_bundle}}"
    "{{lsregister}}" -f -v "{{user_bundle}}"
    @echo "Installed {{user_bundle}}"

launch: install-user
    killall "{{app_name}}" 2>/dev/null || true
    open "{{user_bundle}}"

check:
    swift run WeftStatusSharedChecks
    swift build