Avro2TF/build.gradle at master · mayiming/Avro2TF · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
buildscript {
  repositories {
    jcenter()
  }
  dependencies {
    classpath 'com.jfrog.bintray.gradle:gradle-bintray-plugin:1.+'
  }
}

allprojects {
  apply plugin: "eclipse"
  apply plugin: "idea"

  group = "com.linkedin.avro2tf"
  project.version = "2.1.8"
  repositories {
    jcenter()
    mavenCentral()
    maven {
      url "https://plugins.gradle.org/m2/"
    }
  }
}

subprojects {
  apply plugin: 'com.jfrog.bintray'
  apply plugin: 'maven-publish'
  apply plugin: 'java'

  sourceCompatibility = 1.8

  task sourcesJar(type: Jar, dependsOn: classes) {
    classifier = 'sources'
    from sourceSets.main.allSource
  }

  task javadocJar(type: Jar, dependsOn: javadoc) {
    classifier = 'javadoc'
    from javadoc.destinationDir
  }

  // add javadoc/source jar tasks as artifacts
  artifacts {
    archives sourcesJar, javadocJar
  }

  publishing {
    publications {
      avro2tfPublication(MavenPublication) {
        from components.java
        groupId "com.linkedin.avro2tf"
        artifactId "${project.name}"

        artifact sourcesJar
        artifact javadocJar

        pom {
          name = "${project.name}".toString()
          description = "${project.name}".toString()
          url = 'https://github.com/linkedin/Avro2TF'
          licenses {
            license {
              name = "BSD 2-Clause"
              url = "https://opensource.org/licenses/BSD-2-Clause"
            }
          }
          developers {
            developer {
              id = 'zhangxuhong'
              name = 'Xuhong Zhang'
            }
            developer {
              id = 'cyzhangchenya'
              name = 'Chenya Zhang'
            }
          }
          scm {
            connection = 'https://github.com/linkedin/Avro2TF.git'
            developerConnection = 'git@github.com:linkedin/Avro2TF.git'
            url = 'https://github.com/linkedin/Avro2TF'
          }
        }
      }
    }
  }

  bintray {
    user = project.hasProperty('bintrayUser') ? project.property('bintrayUser') : System.getenv('BINTRAY_USER')
    key = project.hasProperty('bintrayApiKey') ? project.property('bintrayApiKey') : System.getenv('BINTRAY_API_KEY')
    publications = ['avro2tfPublication']
    pkg {
      repo = 'maven'
      name = 'Avro2TF'
      userOrg = 'linkedin'
      licenses = ['BSD 2-CLAUSE']
      vcsUrl = 'https://github.com/linkedin/Avro2TF.git'
      labels = ['tensorflow', 'spark', 'avro']
      publicDownloadNumbers = true
      version {
        name = project.version
        released = new Date()
      }
    }
  }
}