psyc/libpsyc.psy at master · harrand/psyc · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
== debug ==
{
	optimization(0);
	debug_symbols(true);

	_base();
};

== release ==
{
	optimization(3);
	debug_symbols(false);

	_base();
};

== default ==
{
	warning("no build config specified, defaulting to 'llvm debug'");
	debug();
};

== _base ==
{
	add_build_file("src/stdlib/stdlib.psy");
	add_source_directory("src");
	add_source_directory("src/frontend");
	add_source_directory("src/backend");

	add_source_directory("src/backend/ir");
	add_source_directory("src/backend/x64");
	add_source_directory("src/backend/arm64");
	add_source_directory("src/backend/exe");
	//add_source_directory("src/backend/llvm");
};

prog : program mut := zero;

// stores long-running things
global_arena_val : arena mut := zero;
global_arena : arena mut? mut := zero;
// stores long-running strings
string_arena_val : arena mut := zero;
string_arena : arena mut? mut := zero;
// stores short-lived things
scratch_arena_val : arena mut := zero;
scratch_arena : arena mut? mut := zero;

argc : s32 mut := zero;
argv : u8?? mut := zero;
envp : u8?? mut := zero;

setup_arenas : func( -> v0)
{
	global_arena_val = arena_create_virtual_reserve(arena_default_reserve, 4096 * 1024);
	global_arena = ref global_arena_val;
	arena_auto_align(global_arena, 8);

	string_arena_val = arena_create_virtual_reserve(arena_default_reserve, 4096 * 1024);
	string_arena = ref string_arena_val;
	arena_auto_align(string_arena, 1);

	scratch_arena_val = arena_create_virtual_reserve(arena_default_reserve, 4096 * 1024);
	scratch_arena = ref scratch_arena_val;
	arena_auto_align(scratch_arena, 1);
};

destroy_arenas : func( -> v0)
{
	print_arena_summary(global_arena, "global");
	arena_destroy(global_arena);

	print_arena_summary(string_arena, "string");
	arena_destroy(string_arena);

	arena_destroy(scratch_arena);
};

print_arena_summary : func(a : arena mut?, name : u8? -> v0)
{
	putzstr(name);
	putzstr(" arena: ");
	putuint(a->cur);
	putzstr("B");
	if(a->recycling_enabled)
	{
		putzstr(" (free list total: ");
		putuint(free_list_total_size(ref(a->recycle_bin)));
		putzstr("B");
		putzstr(", avg: ");
		putuint(free_list_avg_size(ref(a->recycle_bin)));
		putzstr("B)");
	}
	putchar(10);
	[a] = zero;
};

psyc_setup : func(pargs : program_args? -> bool)
{
	argc = (pargs->argc);
	argv = (pargs->argv);
	envp = (pargs->envp);
	setup_arenas();

	prog.types = tybox_create(1024);
	prog.entrypoint = sstr{.data := "main"; .len := 4;};

	lex_setup();
	grammar_setup(global_arena);
	buildinst_setup();

	prog.debug_symbols = true;
	prog.compile_args = psyc_parse_args(global_arena);
	prog.output.dir = prog.compile_args.output_dir;
	prog.output.name = sstr2zstr(prog.compile_args.output_name, prog.compile_args.output_name_len, string_arena);

	if(prog.compile_args.build_file == zero)
	{
		if(prog.compile_args.requested_version)
		{
			// probably just did psyc -v
			// print the version and return silently
			ver ::= embed("./ver.txt");
			putzstr("Psyc ");
			putbytes(ver.data, ver.len);
			putchar(10);
			return false;
		}
		psyc_error_begin(zero);
		putzstr("no build file specified");
		psyc_error_end(zero);
	}
	if(!file_exists(prog.compile_args.build_file))
	{
		psyc_error_begin(zero);
		putzstr("build file ");
		putchar('"');
		putzstr(prog.compile_args.build_file);
		putchar('"');
		putzstr(" could not be located");
		psyc_error_end(zero);
	}
	return true;
};