dev-templates/c-cpp/flake.nix at main · definfo/dev-templates · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
{
  description = "A Nix-flake-based C/C++ development environment";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";
    flake-compat = {
      url = "github:NixOS/flake-compat";
      flake = false;
    };
    flake-parts = {
      url = "github:hercules-ci/flake-parts";
      inputs.nixpkgs-lib.follows = "nixpkgs";
    };
    pre-commit-hooks = {
      url = "github:cachix/git-hooks.nix";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    treefmt-nix = {
      url = "github:numtide/treefmt-nix";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };

  outputs =
    inputs@{ flake-parts, ... }:
    # See https://flake.parts/module-arguments for module arguments
    flake-parts.lib.mkFlake { inherit inputs; } {
      imports = [
        inputs.treefmt-nix.flakeModule
        inputs.pre-commit-hooks.flakeModule
      ];
      systems = [
        "x86_64-linux"
        "aarch64-linux"

        "aarch64-darwin"
      ];
      perSystem =
        {
          config,
          pkgs,
          ...
        }:
        {
          # https://flake.parts/options/treefmt-nix.html
          # Example: https://github.com/nix-community/buildbot-nix/blob/main/nix/treefmt/flake-module.nix
          treefmt = {
            projectRootFile = "flake.nix";
            settings.global.excludes = [ ];

            programs = {
              clang-format.enable = true;
              cmake-format.enable = true;
              nixfmt.enable = true;
            };

            settings.formatter.cmake-format.includes = [
              "*/CMakeLists.txt"
            ];
          };

          # https://flake.parts/options/git-hooks-nix.html
          # Example: https://github.com/cachix/git-hooks.nix/blob/master/template/flake.nix
          pre-commit.settings.hooks = {
            commitizen.enable = true;
            eclint.enable = true;
            treefmt.enable = true;
          };

          # Equivalent to  inputs'.nixpkgs.legacyPackages.hello;
          # packages.hello = pkgs.hello;

          # NOTE: You can also use `config.pre-commit.devShell` or `config.treefmt.build.devShell`
          devShells.default =
            pkgs.mkShell.override
              {
                # Override stdenv in order to change compiler:
                # stdenv = pkgs.clangStdenv;
              }
              {
                inputsFrom = [
                  config.treefmt.build.devShell
                  config.pre-commit.devShell
                ];

                shellHook = ''
                  echo 1>&2 "Welcome to the development shell!"
                '';

                buildInputs = with pkgs; [
                  # zlib
                  # ncurses
                  # gmp
                  # libffi
                  # pythonManylinuxPackages.manylinux1
                ];

                packages =
                  with pkgs;
                  [
                    cmake
                    # conan
                    # cppcheck
                    # doxygen
                    # gtest
                    # lcov
                    ninja
                    # vcpkg
                    # vcpkg-tool

                    pkg-config
                    # cxxopts
                  ]
                  ++ (if system == "aarch64-darwin" then [ lldb ] else [ gdb ]);

                env = {
                  # LD_LIBRARY_PATH = pkgs.lib.makeLibraryPath buildInputs;
                };
              };
        };
    };
}