codegen.nix

# codegen flake module simplifies vendoring code generation in your repo
# Copyright (C) 2026 Anterior
#
# This program is free software: you can redistribute it and/or modify
# it under the terms of the GNU Affero General Public License as
# published by the Free Software Foundation, version 3 of the
# License.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU Affero General Public License for more details.
#
# You should have received a copy of the GNU Affero General Public License
# along with this program.  If not, see <https://www.gnu.org/licenses/>.

{
  inputs,
  self,
  flake-parts-lib,
  ...
}:
{
  options.perSystem = flake-parts-lib.mkPerSystemOption (
    {
      pkgs,
      lib,
      system,
      config,
      ...
    }:
    let
      inherit (lib) types;
      cfg = config.codegen;
      entry =
        {
          lib,
          config,
          options,
          name,
          ...
        }:
        {
          options = {
            source = lib.mkOption {
              type = types.pathInStore;
              description = "File or directory to treat as the source for this target";
            };
            text = lib.mkOption {
              type = types.nullOr types.str;
              default = null;
              description = "Verbatim content for this file as a string";
            };
          };
          config = {
            source = lib.mkIf (config.text != null) (lib.mkDerivedConfig options.text (pkgs.writeText name));
          };
        };
    in
    {
      options.codegen = {
        enable = lib.mkEnableOption "Enable management of auto generated files";
        files = lib.mkOption {
          type = lib.types.lazyAttrsOf (types.submodule entry);
          description = ''
            Mapping of local path to derivation output for that path

            If the source is a directory and you want to copy its *contents*,
            not the directory itself, make sure to terminate it with a /.
          '';
          default = { };
          example = lib.literalExpression ''
            {
              ".github/workflows".source = "''${github-actions}/";
              "src/schemas".source = "''${ourschemas}/schemas/";
            }
          '';
        };
        root = lib.mkOption {
          type = lib.types.path;
          description = "Root to which the paths in the schema are relative";
          example = lib.literalExpression "./.";
        };
        workingDirPrefix = lib.mkOption {
          type = lib.types.str;
          default = "";
          example = ''"$PRJ_ROOT"/'';
          description = "Path prefix for syncing generated files to the working directory.";
        };
      };
      config = lib.mkIf cfg.enable {
        packages.codegen = pkgs.runCommand "codegen-build" { } (
          ''
            mkdir -p $out
          ''
          + lib.concatLines (
            lib.mapAttrsToList (
              k: v:
              let
                target = "$out/${lib.escapeShellArg k}";
              in
              ''
                mkdir -p ${target}
                rm -rf ${target}
                cp -r ${v.source} ${target}
              ''
            ) cfg.files
          )
        );
        checks.codegen = pkgs.runCommand "codegen-check" { nativeBuildInputs = [ pkgs.diffutils ]; } (
          lib.concatLines (
            lib.mapAttrsToList (
              k: v:
              let
                # Construct separately to avoid copying over the entire working
                # directory to the store.
                storePath = cfg.root + "/${lib.escapeShellArg k}";
              in
              ''
                diff --recursive --brief ${v.source} ${storePath}
                touch $out
              ''
            ) cfg.files
          )
        );
        apps.codegen = {
          type = "app";
          program =
            let
              pkg = pkgs.writeShellApplication {
                name = "codegen-sync";
                runtimeInputs = [ pkgs.rsync ];
                text = lib.concatLines (
                  lib.mapAttrsToList (k: v: ''
                    rsync -ah --delete --checksum --chmod=u+w ${v.source} ${cfg.workingDirPrefix}${lib.escapeShellArg k}
                  '') cfg.files
                );
              };
            in
            lib.getExe pkg;
          meta.description = "synchronize the autogenerated files in the working directory";
        };
      };
    }
  );
}