tibia-study/InspectObjectDialog.qml at main · ReloadBot/tibia-study · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
import QtQuick
import QtQuick.Controls
import QtQuick.Layouts
import qmlcomponents


TibiaDialog {
  id: inspectObjectDialog
  caption: qsTrId("inspect_object_caption")
  width: 450 + 2*TibiaStyle.dialogMarginBorder //450 is the with of the text field in inspect player dialog

  required property var controller

  onReturnPressedFunction: closeDialog
  onCancelPressedFunction: closeDialog

  function closeDialog() {
    if (controller != null) {
      controller.okButtonClicked();
    }
  } //function closeDialog

  initialFocusItem: inspectObjectDialog

  Component {
    id: inspectObjectView64x64

    ColumnLayout {
      property var inspectModel: modelData

      Layout.fillWidth: true
      spacing: TibiaStyle.marginRelated

      RowLayout {
        Layout.fillWidth: true
        spacing: TibiaStyle.marginRelated

        ScalableObjectDisplay {
          Layout.preferredWidth: TibiaStyle.inspectObjectSpriteOuterSize
          Layout.preferredHeight: TibiaStyle.inspectObjectSpriteOuterSize
          scaleFactor: TibiaStyle.inspectObjectScaleFactor
          smoothTextureFiltering: controller != null && controller.clientSettingSmoothFiltering
          showBackground: false

          animated: true
          typeid: inspectModel.appearanceID
          cumulativeCount: inspectModel.objectCount
          upgradeTier: inspectModel.objectUpgradeTier
          liquidType: inspectModel.liquidType
          hookDirection: inspectModel.hookDirection
          decoItemObjectID: inspectModel.decoItemObjectID
        } //ScalableObjectDisplay

        TibiaText {
          Layout.fillWidth: true
          Layout.alignment: Qt.AlignBottom | Qt.AlignLeft
          text: qsTrId("inspect_inspecting").arg(inspectModel.objectName)
          wrapMode: Text.Wrap
        } //TibiaText

        Repeater {
          model: inspectModel.imbumentIcons

          BorderImage {
            Layout.preferredWidth: TibiaStyle.inspectObjectSpriteOuterSize
            Layout.preferredHeight: TibiaStyle.inspectObjectSpriteOuterSize
            border { left: 1; right: 1; top: 1; bottom: 1 }
            source: "/images/1pixel-down-frame.png"
            horizontalTileMode: BorderImage.Repeat
            verticalTileMode: BorderImage.Repeat

            Image {
              anchors.centerIn: parent
              source: modelData
            } //Image
          } //BorderImage
        } //Repeater
      } //RowLayout

      TibiaTextArea {
        id: objectInformation
        Layout.fillWidth: true
        Layout.preferredHeight: 150
        text: inspectModel.objectInformation
        readOnly: true
        wrapMode: TextEdit.Wrap
        KeyNavigation.tab: inspectObjectDialog
        textFormat: TextEdit.RichText
      } //TibiaTextArea
    } //ColumnLayout
  } //Component

  ColumnLayout {
    anchors { left: parent.left; right: parent.right }
    spacing: TibiaStyle.marginUnrelated

    TibiaScrollView {
      id: inspectObjectScrollView
      Layout.fillWidth: true
      Layout.preferredHeight: Math.min(460, inspectObjectViews.height)

      verticalScrollBarPolicy: ScrollBar.AsNeeded

      Flickable {
        boundsBehavior: Flickable.StopAtBounds
        interactive: false //prevent flick behavior on touch screens

        contentHeight: inspectObjectViews.height
        contentWidth: inspectObjectViews.width

        ColumnLayout {
          id: inspectObjectViews
          width: inspectObjectScrollView.width - (height > inspectObjectScrollView.height ? (12+TibiaStyle.marginRelated) : 0)
          spacing: TibiaStyle.marginUnrelated

          Repeater {
            model: controller != null ? controller.inspectObjectList : null

            delegate: inspectObjectView64x64
          } //Repeater
        } //ColumnLayout
      } //Flickable
    } //TibiaScrollView

    TibiaHorizontalSeparator {
      Layout.fillWidth: true
    } //TibiaHorizontalSeparator

    RowLayout {
      Layout.alignment: Qt.AlignRight
      spacing: TibiaStyle.marginRelated

      TibiaIconButton {
        sourceUp: "/images/button-copytoclipboard-up.png"
        sourceDown: "/images/button-copytoclipboard-down.png"
        tooltipText: qsTrId("inspect_copy_information")

        onClicked: {
          if (controller != null) {
            controller.copyToClipboarClicked();
          }
        } //onClicked
      } //TibiaIconButton

      Item {Layout.fillWidth: true}

      TibiaButton {
        text: qsTrId("inspect_open_weapon_proficiency_dialog")
        tooltipText: qsTrId("inspect_open_weapon_proficiency_dialog_tooltip")
        visible: inspectObjectDialog.controller != null && inspectObjectDialog.controller.showProficiencyButton
        Layout.preferredWidth: TibiaStyle.buttonWidthBroad

        onClicked: {
          inspectObjectDialog.controller.openWeaponProficiencyDialogClicked();
        }
      } // TibiaButton

      TibiaButton {
        text: qsTrId("close")

        onClicked: inspectObjectDialog.closeDialog();
      } // TibiaButton
    } // RowLayout
  } // ColumnLayout
} // TibiaDialog