tibia-study/FriendsInvitesPage.qml at main · ReloadBot/tibia-study · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
import QtQuick
import QtQuick.Controls
import QtQuick.Layouts

import qmlcomponents
import qmlenumvalues
import QtQuick.LegacyControls


ColumnLayout {
  id: root
  property var controller: null
  property var initialFocusItem: invitesTable

  TibiaFrame2PixelUpFilled {
    Layout.fillWidth: true
    Layout.preferredHeight: 36
    Layout.alignment: Qt.AlignTop

    RowLayout {
      anchors.fill: parent
      anchors.margins: TibiaStyle.marginRelated

      spacing: TibiaStyle.marginUnrelated * 2
      Layout.bottomMargin: TibiaStyle.marginUnrelated

      ButtonGroup {
        id: tableSelectionGroup

        checkedButton: {
          if (controller != null && controller.shownListType == FriendsInvitesController.ReceivedInvites) {
            return receivedInvitesButton;
          } else if (controller != null && controller.shownListType == FriendsInvitesController.SentInvites) {
            return sentInvitesButton;
          } else if (controller != null && controller.shownListType == FriendsInvitesController.Blacklist) {
            return blacklistButton;
          } else {
            return null;
          }
        }
      }

      Item {
        Layout.fillWidth: true
      }

      TibiaRadioButton {
        id: receivedInvitesButton
        text: qsTrId("friends_received_invites_header").arg(controller != null ? controller.receivedInvites.count : 0)
        ButtonGroup.group: tableSelectionGroup

        onClicked: {
          if (controller != null) {
            controller.shownListType = FriendsInvitesController.ReceivedInvites;
          }
        }
      } // TibiaRadioButton

      TibiaRadioButton {
        id: sentInvitesButton
        text: qsTrId("friends_sent_invites_header").arg(controller != null ? controller.sentInvites.count : 0)
        ButtonGroup.group: tableSelectionGroup

        onClicked: {
          if (controller != null) {
            controller.shownListType = FriendsInvitesController.SentInvites;
          }
        }
      } // TibiaRadioButton

      TibiaRadioButton {
        id: blacklistButton
        text: qsTrId("friends_blacklist_header").arg(controller != null ? controller.blacklist.count : 0)
        ButtonGroup.group: tableSelectionGroup

        onClicked: {
          if (controller != null) {
            controller.shownListType = FriendsInvitesController.Blacklist;
          }
        }
      } // TibiaRadioButton

      Item {
        Layout.fillWidth: true
      }
    } // RowLayout
  } // TibiaFrame2PixelUpFilled

  TibiaTableView {
    id: invitesTable
    Layout.fillWidth: true
    Layout.fillHeight: true
    horizontalScrollBarPolicy: ScrollBar.AlwaysOff
    headerVisible: true
    model: {
      if (controller != null && controller.shownListType == FriendsInvitesController.ReceivedInvites) {
        return controller.receivedInvites;
      } else if (controller != null && controller.shownListType == FriendsInvitesController.SentInvites) {
        return controller.sentInvites;
      } else {
        return null;
      }
    }
    visible: {
      return controller != null && (
        controller.shownListType == FriendsInvitesController.ReceivedInvites ||
        controller.shownListType == FriendsInvitesController.SentInvites
      )
    }

    TableViewColumn {
      role: "maincharName"
      title: qsTrId("friends_invites_mainchar_name")
      width: 290
      movable: false
      resizable: false

      delegate: RowLayout {
        anchors { left: parent.left; right: parent.right }
        spacing: TibiaStyle.marginNarrow

        TibiaText {
          id: mainCharTitle
          Layout.rightMargin: TibiaStyle.marginNarrow
          Layout.leftMargin: TibiaStyle.marginNarrow
          text: model != null ? model.title : ""
          visible: text.length != 0
          styleType: "Caption"
        } //TibiaText

        Item {
          Layout.fillWidth: true
          Layout.preferredHeight: mainCharName.height
          Layout.leftMargin: mainCharTitle.visible ? 0 : TibiaStyle.marginNarrow

          TibiaText {
            id: mainCharName
            anchors { left: parent.left; right: parent.right }
            text: styleData.value

            color: styleData.selected ? TibiaStyle.textFieldSelectionTextColor
                                      : TibiaStyle.textFieldTextColor
          } //TibiaText

        } //Item

        TibiaButton {
          imageSourceUp: "/images/icon-edit.png"
          visible: styleData.selected
          Layout.preferredHeight: mainCharName.height
          Layout.preferredWidth: mainCharName.height

          onClicked: {
            if (controller != null && controller.shownListType == FriendsInvitesController.ReceivedInvites) {
              controller.showContextMenuForReceivedInvite(model.accountID);
            } else if (controller != null && controller.shownListType == FriendsInvitesController.SentInvites) {
              controller.showContextMenuForSentInvite(model.accountID);
            }
          }
        } // TibiaButton

        TibiaVerticalSeparator {
          Layout.fillHeight: true
        } // TibiaVerticalSeparator
      } // delegate RowLayout
    } // TableViewColumn

    TableViewColumn {
      role: "inviterName"
      title: qsTrId("friends_invites_inviter_name")
      width: 260
      movable: false
      resizable: false
    }

    TableViewColumn {
      role: "inviteDate"
      title: qsTrId("date_column_header")
      movable: false
      resizable: false
    }
  } // TibiaTableView

  TibiaTableView {
    id: blacklistTable
    Layout.fillWidth: true
    Layout.fillHeight: true
    horizontalScrollBarPolicy: ScrollBar.AlwaysOff
    headerVisible: true
    model: controller != null ? controller.blacklist : null
    visible: controller != null && controller.shownListType == FriendsInvitesController.Blacklist

    TableViewColumn {
      role: "maincharName"
      title: qsTrId("friends_invites_mainchar_name")
      width: 480
      movable: false
      resizable: false

      delegate: RowLayout {
        spacing: TibiaStyle.marginNarrow

        TibiaText {
          id: mainCharName
          text: styleData.value
          Layout.fillWidth: true
          color: styleData.selected
            ? TibiaStyle.textFieldSelectionTextColor
            : TibiaStyle.textFieldTextColor
          Layout.leftMargin: TibiaStyle.marginNarrow
        }

        TibiaButton {
          imageSourceUp: "/images/icon-edit.png"
          visible: styleData.selected
          Layout.preferredHeight: mainCharName.height
          Layout.preferredWidth: mainCharName.height

          onClicked: {
            if (controller != null) {
              controller.showContextMenuForBlacklistedAccount(model.accountID);
            }
          }
        } // TibiaButton

        TibiaVerticalSeparator {
          Layout.fillHeight: true
        } // TibiaVerticalSeparator
      } // delegate RowLayout
    } // TableViewColumn

    TableViewColumn {
      role: "blacklistDate"
      title: qsTrId("friends_blacklist_date")
      movable: false
      resizable: false
    }
  } // TibiaTableView
} // ColumnLayout