tibia-study/EditVipDialog.qml at main · ReloadBot/tibia-study · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
import QtQuick
import QtQuick.Controls
import QtQuick.Layouts


TibiaDialog {
  id: enterTextDialog
  caption: qsTrId("edit_vip_caption")
  width: 285


  property QtObject controller: null
  property string vipName: "Default Vip Name"
  property int vipIconID: 0
  property string vipDescription: ""
  property bool vipNotify: false
  property var vipGroupInfos: null

  onVipDescriptionChanged: {
    descriptionTextArea.text  = vipDescription;
    descriptionTextArea.cursorPosition = vipDescription.length;
  } //onVipDescriptionChanged

  function sendUpdatedVipData() {
   if(null != controller) {
     controller.onOkClicked(vipIconID, descriptionTextArea.text, notifyCheckBox.checked);
   }
  } //function sendEnteredText()


  onReturnPressedFunction: sendUpdatedVipData
  onCancelPressedFunction: controller!=null ? controller.onCancelClicked : null
  initialFocusItem: descriptionTextArea

  ColumnLayout {
    id: columns
    anchors { left: parent.left; right: parent.right}
    spacing: TibiaStyle.marginUnrelated

    ColumnLayout {
      Layout.fillWidth: true
      spacing: TibiaStyle.marginRelated

      TibiaText {
        id: vipNameText
        Layout.fillWidth: true
        text: vipName
      } //TibiaText

      TibiaHorizontalSeparator {
        Layout.fillWidth: true
      } //TibiaHorizontalSeparator
    } //ColumnLayout

    ColumnLayout{
      Layout.fillWidth: true
      spacing: TibiaStyle.marginRelated

      TibiaText {
        Layout.fillWidth: true
        text: qsTrId("edit_vip_select_type")
      } //TibiaText


      RowLayout {
        spacing: TibiaStyle.marginRelated

        ButtonGroup {
          id: selectedVipIcon
        } //ButtonGroup

        Repeater {
          model: TibiaStyle.numberOfVipIcons

          delegate: TibiaIconSelectionButton {
            iconPath: "image://vip-icons/" + modelData
            onClicked: { vipIconID = modelData; }
            checked: (modelData == vipIconID)
            ButtonGroup.group: selectedVipIcon
          } //TibiaIconButton
        } //Repeater
      } //RowLayout

    } //ColumnLayout


    ColumnLayout{
      Layout.fillWidth: true
      spacing: TibiaStyle.marginRelated

      TibiaText {
        Layout.fillWidth: true
        text: qsTrId("edit_vip_description")
      } //TibiaText


      TibiaTextArea {
        id: descriptionTextArea
        Layout.fillWidth: true
        Layout.preferredHeight: 50
        textFormat: TextEdit.PlainText
        maximumLength: TibiaStyle.maxDescriptionLength

        KeyNavigation.tab: descriptionTextArea
        focus:true
      } //TibiaTextField
    } //ColumnLayout

    TibiaMenuOptionCheckBox {
      id: notifyCheckBox
      text: qsTrId("edit_vip_notify_on_login")
      Layout.fillWidth: true
      checked: vipNotify
    }

    TibiaHorizontalSeparator {
      Layout.fillWidth: true
    } //TibiaHorizontalSeparator

    ColumnLayout{
      Layout.fillWidth: true
      spacing: TibiaStyle.marginRelated

      TibiaText {
        Layout.fillWidth: true
        text: qsTrId("edit_vip_groups_caption")
      } //TibiaText

      ListView {
        id: vipGroupsList
        spacing: TibiaStyle.marginNarrow

        Layout.fillWidth: true
        Layout.preferredHeight: contentHeight
        model: vipGroupInfos

        delegate: TibiaCheckBox {
          width: vipGroupsList.width - 7
          text: modelData.groupName
          checked: modelData.selected

          Binding {
            target: modelData
            property: "selected"
            value: checked
          } //Binding
        } //VipGroupEntry
      } // ListView
    } //ColumnLayout

    TibiaHorizontalSeparator {
      Layout.fillWidth: true
    } //TibiaHorizontalSeparator

    RowLayout {
      Layout.fillWidth: true
      spacing: TibiaStyle.marginUnrelated

      Item {
        Layout.fillWidth: true
      } //Item

      TibiaButton{
        id: okButton
        text: qsTrId("ok")
        onClicked: { sendUpdatedVipData(); }
      } //TibiaButton

      TibiaButton{
        id: cancelButton
        text: qsTrId("cancel")
        onClicked: controller!=null ?  controller.onCancelClicked() : undefined
      } //TibiaButton
    } //RowLayout

  }//ColumnLayout
} //TibiaDialog