tibia-study/EditTextDialog.qml at main · ReloadBot/tibia-study · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
import QtQuick
import QtQuick.Layouts
import qmlcomponents


TibiaDialog {
  id: editTextDialog
  caption: controller != null ? controller.modelData.dialogCaption : qsTrId("edit_text_caption")
  width: 313

  property var controller: null

  onReturnPressedFunction: function() { if (confirmButton.visible) confirmButton.clicked() }

  onCancelPressedFunction: function() { cancelButton.clicked() }

  initialFocusItem: editTextArea

  ColumnLayout {
    height: 400
    width: parent.width
    spacing: TibiaStyle.marginUnrelated

    ColumnLayout {
      id: mainLayout
      spacing: TibiaStyle.marginUnrelated

      RowLayout {
        spacing: TibiaStyle.marginUnrelated
        visible: descriptionText.text.length > 0

        Image {
          source: "/images/edit-list-logo.png"
          visible: !appearanceInstanceViewer.visible
        } //Image

        SingleObjectAppearanceInstanceRenderer {
          id: appearanceInstanceViewer
          Layout.preferredWidth: TibiaStyle.mapWindowPixelPerField
          Layout.preferredHeight: TibiaStyle.mapWindowPixelPerField

          animated: true
          typeid: controller != null ? controller.modelData.objectID : 0
          cumulativeCount: controller != null ? controller.modelData.objectCount :0
          liquidType: controller != null ? controller.modelData.liquidType : ObjectAppearanceInstance.EMPTY
          hookDirection: controller != null ? controller.modelData.hookDirection : ObjectAppearanceInstance.NONE
        } //SingleObjectAppearanceInstanceRenderer

        TibiaText {
          id: descriptionText
          text: controller != null ? controller.modelData.editDescription : ""
          Layout.fillWidth: true
          wrapMode: Text.Wrap
        } //TibiaText
      } // RowLayout

      RowLayout {
        id: phishingWarning
        spacing: TibiaStyle.marginUnrelated
        visible: controller != null && controller.modelData.showPhishingWarning

        Image {
          source: "/images/skin/classic/warning-triangle.png"
        } //Image

        TibiaText {
          Layout.fillWidth: true
          styleType: "MessageCritical"
          text: qsTrId("edit_phishing_warning")
          wrapMode: Text.Wrap
        } //TibiaText
      } //RowLayout

      RowLayout {
        id: recentlyTradedWarning
        spacing: TibiaStyle.marginUnrelated
        visible: controller != null && controller.modelData.showRecentlyTradedWarning

        Item {
          Layout.preferredHeight: 32
          Layout.preferredWidth: 32
          Image {
            anchors.centerIn: parent
            source: "/images/skin/classic/show-gui-help-orange.png"
          } //Image
        } //Item


        TibiaText {
          Layout.fillWidth: true
          styleType: "MessageWarning"
          text: qsTrId("edit_recently_traded_warning")
          wrapMode: Text.Wrap
        } //TibiaText
      } //RowLayout

      TibiaTextArea {
        id: editTextArea
        Layout.fillWidth: true
        Layout.fillHeight: true
        text: controller != null ? controller.modelData.editText : ""
        readOnly: controller != null ? !controller.modelData.textIsEditable : false
        maximumLength: controller != null ? controller.modelData.maximumEditTextLength : -1
        wrapMode: TextEdit.Wrap
        KeyNavigation.tab: editTextArea

        onActiveFocusChanged: {
          if (focus && !readOnly && !cursorMovedToEnd) {
            scrollToEndTimer.start();
          } else if (readOnly) {
            editTextArea.cursorPosition = 0;
          }
        } //onActiveFocusChanged

        Timer {
          id: scrollToEndTimer
          interval: 0
          repeat: false
          onTriggered: editTextArea.pushCursorToEnd()
        } //Timer

        property bool cursorMovedToEnd: false
        function pushCursorToEnd() {
          editTextArea.cursorPosition = editTextArea.length;
          cursorMovedToEnd = true;
        } //function pushCursorToEnd()
      } // TibiaTextArea
    } // ColumnLayout

    ColumnLayout {
      id: bottomMenuBar
      Layout.alignment: Qt.AlignBottom
      spacing: TibiaStyle.marginUnrelated

      TibiaHorizontalSeparator {
        Layout.fillWidth: true
      } //TibiaHorizontalSeparator

      RowLayout {
        spacing: TibiaStyle.marginRelated

        TibiaButton {
          Layout.preferredWidth: TibiaStyle.buttonWidthBroad

          text: qsTrId("context_report_text")
          visible: controller != null && controller.modelData.showReportButton

          onClicked: {
            if (controller != null) {
              controller.reportText();
            }
          } //onClicked
        } //TibiaButton

        Item {
          Layout.fillWidth: true
        } //Item

        TibiaButton {
          id: confirmButton
          text: qsTrId("ok")
          visible: controller != null ? controller.modelData.textIsEditable : true

          onClicked: {
            if (controller != null) {
              controller.submitNewText(editTextArea.text);
            }
          } //onClicked
        } // TibiaButton

        TibiaButton {
          id: cancelButton
          text: confirmButton.visible ? qsTrId("cancel") : qsTrId("ok")

          onClicked: {
            if (controller != null) {
              controller.abortEditing();
            }
          } //onClicked
        } // TibiaButton
      } // RowLayout
    } // ColumnLayout
  } // Item
} // TibiaDialog