external_devshell/flake.nix at 16.2 · ProjectCiRCLE-ROM/external_devshell · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
{
  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs/nixos-26.05";
  };

  outputs =
    { nixpkgs, ... }:
    let
      forEachSystem = nixpkgs.lib.genAttrs nixpkgs.lib.systems.flakeExposed;
      lib = nixpkgs.lib;
      fhs =
        name: pkgs: attrs: additionalPkgs:
        pkgs.buildFHSEnvBubblewrap (
          {
            inherit name;
            targetPkgs =
              pkgs:
              with pkgs;
              [
                bc
                bison
                ccache
                clang_20
                clangStdenv
                dtc
                elfutils
                elfutils.dev
                flex
                fontconfig
                freetype
                gcc
                gcc.cc
                git
                git-lfs
                git-repo
                glibc
                glibc.dev
                pkgsi686Linux.glibc.dev
                gnumake
                go
                imagemagick
                libbsd.dev
                libelf
                libgcc
                lld_20
                llvm_20
                libxcrypt-legacy
                ncurses5
                ncurses
                ncurses.dev
                openssl
                openssl.dev
                openssh
                perl
                pkgconf
                pngcrush
                ps
                python3
                rclone
                roboto
                rsync
                unzip
                util-linux
                which
                zip
                zlib

                # misc packages
                payload-dumper-go
                strace

                # some SDK tools need this
                alsa-lib

                # for emulator
                libpulseaudio
                libpng
                nss
                nspr
                expat
                libdrm
                libbsd
                xcb-util-cursor
                libxkbcommon
                libsForQt5.qt5.qtwayland
                xwayland
                crosvm
                dbus
                mesa
                libx11
                libxcursor
                libxcb
                libxcb-cursor
                xcb-util-cursor
                xcbutilimage
                xcbutilwm
                xcbutilkeysyms
                xcbutilrenderutil
                libxi
                libxext
                libxkbfile
                libsm
                libice
              ] ++ additionalPkgs;
            profile =
              let
                bootanimPythonEnv = pkgs.python3.withPackages (ps: with ps; [
                  pillow
                  numpy
                ]);
              in
              builtins.readFile (
              (pkgs.formats.keyValue { }).generate "" (
                lib.mapAttrs'
                  (name: value: {
                    name = "export ${name}";
                    inherit value;
                  })
                  {
                    LIBGCC_DIR = "${pkgs.libgcc.out}/lib/gcc/${pkgs.libgcc.stdenv.buildPlatform.config}/${pkgs.libgcc.version}";
                    FONTCONFIG_FILE = with pkgs; makeFontsConf { fontDirectories = [ roboto ]; };
                    BOOTANIM_PYTHON_ENV="${bootanimPythonEnv}";
                  }
              )
            );
            extraBuildCommands =
              let
                cuttlefishCapabilities = pkgs.writeShellScript "" ''
                  #!${pkgs.runtimeShell}
                  echo "capability_check"
                  echo "qemu_cli"
                  echo "crosvm"
                  echo -n "vsock"
                '';
              in
              ''
                mkdir -p $out/usr/lib64/cuttlefish-common/bin
                ln -s ${cuttlefishCapabilities} $out/usr/lib64/cuttlefish-common/bin/capability_query.py
              '';
          }
          // attrs
        );
    in
    rec {
      packages = forEachSystem (
        system:
        let
          pkgs = import nixpkgs { inherit system; };
        in
        {
          direnvShell = (
            pkgs.mkShell {
              packages = [
                (pkgs.writeShellApplication {
                  name = "aosp-env";
                  text = ''nix develop path:external/devshell'';
                })
                packages.${system}.execShell
              ];
            }
          );
          execShell = fhs "exec-aosp-env" pkgs { } [ ];
          aautoShell =
            let
              pkgs = import nixpkgs { inherit system; };
            in
            (fhs "aauto-env" pkgs { runScript = "bash"; } [ pkgs.llvmPackages_20.libcxx ]).env;
        }
      );
      devShell = forEachSystem (
        system:
        let
          pkgs = import nixpkgs { inherit system; };
        in
        (fhs "aosp-env" pkgs { runScript = "bash"; } [ ]).env
      );
      formatter = forEachSystem (
        system:
        let
          pkgs = import nixpkgs { inherit system; };
        in
        pkgs.nixfmt-rfc-style
      );
    };
}