build.gradle

plugins {
    id 'fabric-loom' version '1.8-SNAPSHOT'
    id 'maven-publish'
    id 'com.github.johnrengelman.shadow' version '8.1.1'
}

sourceCompatibility = JavaVersion.VERSION_21
targetCompatibility = JavaVersion.VERSION_21

version = "${project.mod_version}"
group = 'me.neovitalism'

repositories {
    mavenCentral()
}

dependencies {
    minecraft "com.mojang:minecraft:${project.minecraft_version}"
    mappings "net.fabricmc:yarn:${project.yarn_mappings}:v2"
    modImplementation "net.fabricmc:fabric-loader:${project.loader_version}"
    modImplementation "net.fabricmc.fabric-api:fabric-api:${project.fabric_api_version}"
    implementation 'net.kyori:adventure-text-minimessage:4.17.0'
    implementation "net.kyori:adventure-text-serializer-gson:4.17.0"
    shadow(implementation (group: 'org.yaml', name: 'snakeyaml', version: '2.0'))
    modImplementation include("net.kyori:adventure-platform-fabric:5.14.1")
    implementation include('org.mariadb.jdbc:mariadb-java-client:3.5.3')
    implementation include('com.zaxxer:HikariCP:5.1.0')
    compileOnly 'net.luckperms:api:5.4'
}

processResources {
    filesMatching("fabric.mod.json") {
        expand(Map.of(
                "version", "${project.mod_version}",
                "loader_version", "${project.loader_version}",
                "minecraft_version", "${project.minecraft_version}"
        ))
    }
}

tasks.withType(JavaCompile).configureEach {
    it.options.release = 21
}

shadowJar {
    configurations = [project.configurations.shadow]
    relocate "org.yaml", "me.neovitalism.neoapi.shadow.org.yaml"
    relocate "org.mariadb", "me.neovitalism.neoapi.shadow.org.mariadb"
}

remapJar {
    dependsOn(shadowJar)
    inputFile = tasks.shadowJar.archiveFile
}

publishing {
    publications {
        maven(MavenPublication) {
            groupId = 'me.neovitalism'
            artifactId = 'NeoAPI'
            version = "${project.version}"
            artifact(remapJar)
        }
    }
}

tasks.build.finalizedBy(publishToMavenLocal)