TParallel.ForEach<T> N'éxist plus dans l'official System.Threading.pas

[MBenDelphi]

var
Liste: TList;
begin
Liste := TList.Create;
try
// Remplir la liste
Liste.Add('Fichier1.txt');
Liste.Add('Fichier2.txt');
Liste.Add('Fichier3.txt');

// Traiter chaque élément en parallèle
TParallel.ForEach<string>(Liste,
  procedure(const Element: string)
  begin
    TraiterFichier(Element);
  end
);

finally
Liste.Free;
end;
end;

[MBenDelphi]

the new impl since TParallel is sealed in System.Threading so helper for System.Threading.TParallel will not works:

unit API.ParallelHelper;

interface

uses
  System.SysUtils,
  System.Threading,
  System.Generics.Collections;

type
  TcProc<T> = reference to procedure(const aArg: T);

  TParallelEx = class sealed
  public
    class procedure ForEach<T>(
      const ASource: TArray<T>;
      const AProc:   TcProc<T>); overload; static;

    class procedure ForEach<T>(
      const ASource: TArray<T>;
      const AProc:   TProc<T>); overload; static;

    class procedure ForEach<T>(
      const ASource: TEnumerable<T>;
      const AProc:   TcProc<T>); overload; static;

    class procedure ForEach<T>(
      const ASource: TEnumerable<T>;
      const AProc:   TProc<T>); overload; static;
  end;

implementation

class procedure TParallelEx.ForEach<T>(
  const ASource: TArray<T>;
  const AProc:   TcProc<T>);
begin
  if Length(ASource) = 0 then Exit;
  TParallelArray.For<T>(ASource,
    procedure(const AValues: array of T; AFrom, ATo: NativeInt)
    begin
      var I := AFrom;
      while I <= ATo do
      begin
        AProc(AValues[I]);
        Inc(I);
      end;
    end);
end;

class procedure TParallelEx.ForEach<T>(
  const ASource: TArray<T>;
  const AProc: TProc<T>);
begin
  if Length(ASource) = 0 then Exit;
  TParallelArray.For<T>(ASource,
    procedure(const AValues: array of T; AFrom, ATo: NativeInt)
    begin
      var I := AFrom;
      while I <= ATo do
      begin
        AProc(AValues[I]);
        Inc(I);
      end;
    end);
end;

class procedure TParallelEx.ForEach<T>(
  const ASource: TEnumerable<T>;
  const AProc:   TcProc<T>);
begin
  TParallelEx.ForEach<T>(ASource.ToArray, AProc);
end;

class procedure TParallelEx.ForEach<T>(
  const ASource: TEnumerable<T>;
  const AProc: TProc<T>);
begin
  TParallelEx.ForEach<T>(ASource.ToArray, AProc);
end;

end.