How do I have to type cast the first element when using initializer lists?

[ghost]

The sample code for using initializer lists to initialize both Array and List involve the type casting of the first element:

https://github.com/AdeptLanguage/Adept/wiki/Array#array-literals

https://github.com/AdeptLanguage/Adept/wiki/List#list-literals

[IsaacShelton]

The reason is because otherwise the initializer list would be an initializer list of initializer lists.

board <<int> List> Array = {
    {0, 0, 0, 0} as <int> Array,
    {0, 0, 0, 0},
    {0, 0, 0, 0},
    {0, 0, 0, 0}
}

vs

board <<int> InitializerList> Array = {
    {0, 0, 0, 0},
    {0, 0, 0, 0},
    {0, 0, 0, 0},
    {0, 0, 0, 0}
}

The Adept standard library currently only supports casting from initializer lists to collections, not initializer lists of initializer lists to collections of collections. This enables us to have zero heap allocations when initializing N-d arrays and avoid having to describe an arbitrary collection.

You can always define your own additional conversions however:

import basics

implicit func __as__(initializer <<$T> InitializerList> InitializerList) <<$T> List> List {
    list <<$T> List> List

    each <$T> InitializerList in initializer {
        list.add(it as <$T> List)
    }
    
    return list.commit()
}

func __as__(initializer <<$T> InitializerList> InitializerList) <<$S> InitializerList> InitializerList {
    result *<<$S> InitializerList> InitializerList = &initializer as *<<$S> InitializerList> InitializerList

    repeat static initializer.length {
        (*result)[idx] = initializer[idx] as <$S> InitializerList
    }

    return *result
}

// Allow <<long> InitializerList> InitializerList for <<int> List> List
implicit func __as__(initializer <<long> InitializerList> InitializerList) <<int> List> List
    = initializer as <<int> InitializerList> InitializerList as <<int> List> List

// Allow <double> InitializerList for <float> List
implicit func __as__(initializer <<double> InitializerList> InitializerList) <<float> List> List
    = initializer as <<float> InitializerList> InitializerList as <<float> List> List

func main {
    numbers <<int> List> List = {
        {1, 2, 3},
        {4, 5, 6},
        {7, 8, 9},
    }

    each <int> List in numbers {
        print(it)
    }
}

although it gets kind of ugly.