common/build.gradle at dev · 89-49/common · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
plugins {
    id 'java-library'   //api()를 사용하기 위한 플러그인
    id 'maven-publish' // 빌드된 아티팩트를 Maven 저장소에 배포하기 위한 플러그인
    id 'org.springframework.boot' version '3.5.13'
    id 'io.spring.dependency-management' version '1.1.7'
}

group = 'org.pgsg'
version = '0.3.2-SNAPSHOT'
description = 'common'

java {
    toolchain {
        languageVersion = JavaLanguageVersion.of(21)
    }
}

bootJar { enabled = false }
jar {
    enabled = true
    archiveClassifier.set('') // 일반 jar 생성
}

repositories {
    mavenCentral()
    maven { url 'https://repo.spring.io/milestone' }
}

ext {
    set('springCloudVersion', "2025.0.1")
}

dependencies {
    api 'org.springframework.boot:spring-boot-starter-validation'
    api 'org.springframework.boot:spring-boot-starter-data-jpa'
    api 'org.springframework.kafka:spring-kafka'
    api 'org.springframework.boot:spring-boot-starter-security'
    api 'org.springframework.boot:spring-boot-starter-web'
    api 'org.springframework.cloud:spring-cloud-starter-config'
    api 'org.springframework.cloud:spring-cloud-starter-loadbalancer'
    api 'org.springframework.cloud:spring-cloud-starter-netflix-eureka-client'
    api 'org.springframework.boot:spring-boot-starter-oauth2-resource-server'
    api 'org.springframework.cloud:spring-cloud-starter-openfeign'

    api "org.springframework.boot:spring-boot-starter-aop"
    api "io.github.resilience4j:resilience4j-spring-boot3:2.2.0"
    api 'io.github.resilience4j:resilience4j-circuitbreaker'
    api 'io.github.resilience4j:resilience4j-retry'

    // Spring Boot 3.5.13 버전에 호환
    api 'org.springdoc:springdoc-openapi-starter-webmvc-ui:2.8.8'

    api "com.github.danielwegener:logback-kafka-appender:0.2.0-RC2"
    api 'net.logstash.logback:logstash-logback-encoder:7.4'
    api 'com.github.loki4j:loki-logback-appender:1.4.1'

    //모니터링
    api 'org.springframework.boot:spring-boot-starter-actuator'
    api 'io.micrometer:micrometer-registry-prometheus'

    // Zipkin
    api 'io.micrometer:micrometer-tracing-bridge-brave'
    api 'io.zipkin.reporter2:zipkin-reporter-brave'
    api 'io.github.openfeign:feign-micrometer'
    api 'io.zipkin.reporter2:zipkin-sender-okhttp3'

    api 'io.github.openfeign.querydsl:querydsl-jpa:6.8'
    annotationProcessor 'io.github.openfeign.querydsl:querydsl-apt:6.8:jpa'
    annotationProcessor 'jakarta.annotation:jakarta.annotation-api'
    annotationProcessor 'jakarta.persistence:jakarta.persistence-api'

    compileOnly 'org.projectlombok:lombok'
    annotationProcessor 'org.projectlombok:lombok'

    // Jwt 관련 기능에 필요한 의존성
    implementation 'io.jsonwebtoken:jjwt-api:0.12.6'
    implementation 'io.jsonwebtoken:jjwt-impl:0.12.6'
    implementation 'io.jsonwebtoken:jjwt-jackson:0.12.6'

    testImplementation 'org.springframework.boot:spring-boot-starter-test'
    testImplementation 'org.springframework.boot:spring-boot-starter-web'
    testImplementation 'org.springframework.security:spring-security-test'
    testCompileOnly 'org.projectlombok:lombok'
    testRuntimeOnly 'org.junit.platform:junit-platform-launcher'
    testAnnotationProcessor 'org.projectlombok:lombok'
}

configurations.configureEach {
    // spring boot 3.5.13에 호환되는 버전을 사용하도록 설정(현재는 4.0대 버전에 맞는 버전을 주입하게 됨)
    resolutionStrategy {
        force "io.github.resilience4j:resilience4j-spring-boot3:2.2.0"
        force "io.github.resilience4j:resilience4j-circuitbreaker:2.2.0"
        force "io.github.resilience4j:resilience4j-retry:2.2.0"
    }
}

publishing {
    publications {
        gpr(MavenPublication) {
            from components.java
            artifactId = 'common'
        }
    }
    repositories {
        maven {
            name = "GitHubPackages" // 저장소 별칭
            url = uri("https://maven.pkg.github.com/89-49/common") // GitHub Packages 저장소 주소
            credentials {
                username = findProperty('gpr.user') ?: System.getenv('GPR_USER')
                password = findProperty('gpr.token') ?: System.getenv('GPR_TOKEN')
            }
        }
    }
}

dependencyManagement {
    imports {
        mavenBom "org.springframework.cloud:spring-cloud-dependencies:${springCloudVersion}"
    }
}

def querydslDir = layout.buildDirectory.dir("generated/querydsl").get().asFile

sourceSets {
    main.java.srcDirs += [ querydslDir ]
}


tasks.withType(JavaCompile).configureEach {
    options.generatedSourceOutputDirectory=file(querydslDir)
}

clean {
    delete querydslDir
}

tasks.named('test') {
    useJUnitPlatform()
}